home *** CD-ROM | disk | FTP | other *** search
/ Commodore 64 Scene Diskmags Assortment / Playback_07_1992_-_de.d64 / komplan v2.0 (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  13KB  |  366 lines
  1. 1 rem +                          +
  2. 2 rem   (c)'89 ralf nikolai
  3. 5 rem          karlsruhe
  4. 6 rem +                          +
  5. 7 rem
  6. 10 ip=50768:gt=51006
  7. 20 ifi=0theni=1:load"komplan.masch",8,1
  8. 30 ml%=10:ks%=1:dimf$(6,9),r$(6,9),kk$(20),kl$(20)
  9. 40 fori=1to6:readwt$(i):nexti:gosub6000:goto500
  10. 50 print#4,chr$(15);a$;chr$(8):sys51431:a%=peek(2):return
  11. 100 print"[147]";:a$=str$(st%):rn=31:gosub800
  12. 110 st%=0:print"maximale zahl stunden pro tag ";:sysip,1:inputst%:ifst%=0then500
  13. 120 print:fori=1tost%:print"beginn der";i;"[157]. stunde ";
  14. 130 a$=zb$(i):rn=2:gosub800:zb$(i)="":sysip,5:inputzb$(i):printtab(14)
  15. 140 a$=ze$(i):rn=9:gosub800:ze$(i)="":print"ende   ";:sysip,5:inputze$(i):nexti
  16. 150 print"[147]abspeichern der zeiten:[154]":print
  17. 160 print"zeiten abspeichen (j/n) ? ";
  18. 170 sysgt,0,a$:ifa$="n"then500
  19. 180 goto6200
  20. 200 print"[147]die laenge der faecher- und raumbe-":print
  21. 210 print"zeichnungen ist maximal 10 buchstaben !"
  22. 220 print"mit _[146] koennen sie verbessern."
  23. 230 poke211,0:poke214,24:sys58732:print"a=abbruch     w=weiter";
  24. 240 print"":gosub900:geta$:ifa$="a"then500
  25. 250 ifa$<>"w"then240
  26. 260 poke198,0:fori=1to6:print"[147]";wt$(i):print"[154]"
  27. 270 forj=1tost%:printj;"[157]. stunde (";zb$(j);"-";ze$(j);") ";
  28. 280 f$(i,j)="":sysip,10:inputf$(i,j):iff$(i,j)<>"_"thengosub7000:goto300
  29. 290 ifj>1thenj=j-1:print:print"[145][145][145]";
  30. 300 printtab(17);:r$(i,j)="":gosub7100:print"raum nr. ";:sysip,10:inputr$(i,j)
  31. 310 ifr$(i,j)="_"thenj=j-1:print:print"[145][145][145]";:nextj
  32. 320 nextj,i
  33. 330 print"[147]wie oft nachmittagsunterricht ";:sysip,1:inputno%:ifno%=0then380
  34. 340 fori=1tono%:print:printi;"[157]. nachmittagsunterricht ";:sysip,30:inputnm$(i)
  35. 350 print"  tag    ";:sysip,10:inputnt$(i)
  36. 360 print"  beginn ";:sysip,5:inputnb$(i)
  37. 370 print"  ende   ";:sysip,5:inputne$(i):nexti
  38. 380 kl$="":hj$="":sj$="":vn$="":nn$=""
  39. 400 print"[147]klasse ";:a$=kl$:rn=2:ml%=20:gosub800:kl$="":sysip,20:inputkl$:print
  40. 410 print"halbjahr (1/2) ";:a$=hj$:rn=2:ml%=1:gosub800:hj$="":sysip,1:inputhj$:print
  41. 420 print"schuljahr ";:a$=sj$:rn=2:ml%=9:gosub800:sj$="":sysip,9:inputsj$:print
  42. 430 print"vorname ";:a$=vn$:rn=2:ml%=28:gosub800:vn$="":sysip,28:inputvn$:print
  43. 440 print"nachname ";:a$=nn$:rn=2:ml%=27:gosub800:nn$="":sysip,27:inputnn$
  44. 500 ml%=10:sys52332:print"[147]":poke53280,0:poke53281,0
  45. 510 print"waehlen sie:":print
  46. 520 print" 1 [154]> eingabe":print
  47. 530 print" 2 [154]> diskettenverwaltung":print
  48. 540 print" 3 [154]> kontrolle":print
  49. 550 print" 4 [154]> verbessern":print
  50. 560 print" 5 [154]> ausdrucken":print
  51. 570 print" 6 [154]> kuerzel":print
  52. 580 print" 7 [154]> ende":print
  53. 590 printtab(10);"ihre wahl (1-7) ? ";
  54. 600 sys51739:sysgt,7,a$:sys51913
  55. 610 print"[154]":onval(a$)goto200,3500,1500,2000,4000,5000
  56. 620 print"falls irrtum restore [154]druecken"
  57. 630 end
  58. 800 yy=peek(214):xx=peek(211):poke211,xx+rn:poke214,yy:sys58732:ifyy>23thenyy=23
  59. 810 printleft$(a$,ml%):poke211,xx:poke214,yy:sys58732:return
  60. 900 print:printtab(10)"[154]taste[146]";:poke198,0:wait198,1:print:return
  61. 1000 print"[147]stundenplan laden:[154]":print
  62. 1010 close15:close8:open15,8,15:open8,8,8,"0:"+a$+".st,p,r"
  63. 1020 print:print"[154]floppy uebergibt ";a$;"[154] an c 64":print
  64. 1030 input#15,a$,b$,c$,d$:if(val(a$)<>0)thenclose8:close15:sys50622:goto3500
  65. 1040 input#8,st%:fori=1tost%:input#8,zb$(i):ifzb$(i)="[166]"thenzb$(i)=""
  66. 1050 nexti:fori=1tost%:input#8,ze$(i):ifze$(i)="[166]"thenze$(i)=""
  67. 1060 nexti:fori=1to6:forj=1tost%
  68. 1070 input#8,f$(i,j),r$(i,j):iff$(i,j)="[166]"thenf$(i,j)=""
  69. 1080 ifr$(i,j)="[166]"thenr$(i,j)=""
  70. 1090 nextj,i:input#8,no%:ifno%=0then1160
  71. 1100 fori=1tono%:input#8,nm$(i),nt$(i),nb$(i),ne$(i)
  72. 1110 ifnm$(i)="[166]"thennm$(i)=""
  73. 1120 ifnt$(i)="[166]"thennt$(i)=""
  74. 1130 ifnb$(i)="[166]"thennb$(i)=""
  75. 1140 ifne$(i)="[166]"thenne$(i)=""
  76. 1150 nexti
  77. 1160 input#8,kl$,hj$,sj$,vn$,nn$:close8
  78. 1170 ifkl$="[166]"thenkl$=""
  79. 1180 ifhj$="[166]"thenhj$=""
  80. 1190 ifsj$="[166]"thensj$=""
  81. 1200 ifvn$="[166]"thenvn$=""
  82. 1210 ifnn$="[166]"thennn$=""
  83. 1220 input#15,a$,b$,c$,d$:close15:ifval(a$)=0then500
  84. 1230 sys50622:goto500
  85. 1500 print"[147]vorname      : ";vn$
  86. 1510 print:print"nachname     : ";nn$
  87. 1520 print:print"klasse/halbj.: ";kl$;:ifhj$<>""thenprint"   ";hj$;". halbjahr"
  88. 1530 ifhj$=""thenprint
  89. 1540 print:print"schuljahr    : ";sj$
  90. 1550 print:gosub900:print"[147]zeiten:[154]":print
  91. 1560 fori=1tost%:printi;"[157]. stunde von ";:iflen(zb$(i))<6thenprintspc(5-len(zb$(i)))
  92. 1570 printzb$(i);" uhr bis ";:iflen(ze$(i))<6thenprintspc(5-len(ze$(i)));
  93. 1580 printze$(i);" uhr":nexti:gosub900
  94. 1590 fori=1to6:print"[147]";wt$(i):print"[154]":forj=1tost%
  95. 1600 printj;"[157]. stunde: ";f$(i,j);spc(11-len(f$(i,j)));"raum: ";r$(i,j):print
  96. 1610 nextj:gosub900:nexti
  97. 1620 print"[147]nachmittagsunterricht:[154]":print
  98. 1630 ifno%=0thenprint" k e i n e r":goto1650
  99. 1640 fori=1tono%:printnt$(i)"s (";nb$(i);"-";ne$(i);"): ";nm$(i):print:nexti
  100. 1650 gosub900:goto500
  101. 2000 print"[147]das koennen sie aendern:":print:print
  102. 2010 print" 1 [154]> einzelne stunden":print
  103. 2020 print" 2 [154]> nachmittagsunterricht":print
  104. 2030 print" 3 [154]> weitere daten (name,klasse,etc.)":print
  105. 2040 print" 4 [154]> stundenbeginn/-ende":print
  106. 2050 print" 5 [154]> gar nichts":print:print
  107. 2060 printtab(10);"ihre wahl (1-5) ? ";
  108. 2070 sysgt,5,a$:print"[154]":onval(a$)goto2200,2500,400,100,500
  109. 2200 i=1
  110. 2210 print"[147]";wt$(i):print"[154]":sys52122:forj=1tost%
  111. 2220 printj;"[157]. stunde (";zb$(j);"-";ze$(j);") [152]";
  112. 2230 poke211,26:sys58732:printf$(i,j);:iff$(i,j)=""thenprint"[144]***";
  113. 2240 print:printtab(18);"[154]raum nr.  [152]";r$(i,j);:ifr$(i,j)=""thenprint"[144]***";
  114. 2250 print"[154]":nextj:print"";
  115. 2260 j=1:pl=25:a%=peek(55297+pl+40*(j+2)):sys51237,8,0,pl,j+2
  116. 2270 pl=27:if(j/2)=int(j/2)thenpl=25
  117. 2280 geta$:ifa$=""then2280
  118. 2290 ifa$="_"thensys52259:goto500
  119. 2300 ifa$="+"theni=i+1:ifi=7theni=1
  120. 2310 ifa$="-"theni=i-1:ifi=0theni=6
  121. 2320 if(a$="+")or(a$="-")thensys51237,a%,2:goto2210
  122. 2330 ifa$="[145]"thenj=j-1:ifj=0thenj=st%*2
  123. 2340 ifa$=""thenj=j+1:if(j>st%*2)thenj=1
  124. 2350 if(a$="[145]")or(a$="")thenrn=a%:a%=peek(55297+pl+40*(j+2)):sys51237,rn,1,pl,j+2
  125. 2360 ifa$<>chr$(13)then2270
  126. 2370 sys52316:xx=26:ifpl=27thenxx=24
  127. 2380 a$="":poke211,xx:poke214,j+2:sys58732:sys51333:sysip,10:inputa$:sys52326
  128. 2390 print"[144]":poke51062,6:poke6,34:sysgt,0,b$:poke51062,203:print"";:ifa$=" "thena$=""
  129. 2400 a%=15:ifa$=""thena%=0:poke211,xx+2:poke214,j+2:sys58732:print"[144]***"
  130. 2410 if(j/2)=int(j/2)thenr$(i,int(j/2))=a$:goto2270
  131. 2420 f$(i,int(j/2)+1)=a$:goto2270
  132. 2500 print"[147]nachmittagsunterricht:[154]":print:print"wie oft woechentlich ?";no%;"[157][157][157][157]";
  133. 2510 sysip,1:inputno%:ifno%=0then500
  134. 2520 print:ml%=17:fori=1tono%:print" fach ";
  135. 2530 a$=nm$(i):rn=2:gosub800:sysip,30:inputnm$(i):print" tag  ";
  136. 2540 a$=nt$(i):rn=2:gosub800:sysip,10:inputnt$(i)
  137. 2550 print" von  ";:a$=nb$(i):rn=2:gosub800:sysip,5:inputnb$(i):print" bis  ";
  138. 2560 a$=ne$(i):rn=2:gosub800:sysip,5:inputne$(i):print:nexti
  139. 2570 ml%=10:goto500
  140. 3000 print"[147]stundenplan abspeichern:[154]":print:ifst%=0then500
  141. 3010 a$="":print"name (1-13 buchstaben) ";:sysip,13:inputa$:ifa$=""then500
  142. 3020 close15:close8:open15,8,15:open8,8,8,"0:"+a$+".st,p,w"
  143. 3030 print:print"c 64 uebergibt ";a$;"[154] an floppy":print
  144. 3040 l$=chr$(13):print#8,st%:fori=1tost%:ifzb$(i)=""thenzb$(i)="[166]"
  145. 3050 print#8,zb$(i):ifzb$(i)="[166]"thenzb$(i)=""
  146. 3060 nexti:fori=1tost%:ifze$(i)=""thenze$(i)="[166]"
  147. 3070 print#8,ze$(i):ifze$(i)="[166]"thenze$(i)=""
  148. 3080 nexti:fori=1to6:forj=1tost%:iff$(i,j)=""thenf$(i,j)="[166]"
  149. 3090 ifr$(i,j)=""thenr$(i,j)="[166]"
  150. 3100 print#8,f$(i,j)l$r$(i,j):iff$(i,j)="[166]"thenf$(i,j)=""
  151. 3110 ifr$(i,j)="[166]"thenr$(i,j)=""
  152. 3120 nextj,i:print#8,no%:ifno%=0then3230
  153. 3130 fori=1tono%:ifnm$(i)=""thennm$(i)="[166]"
  154. 3140 ifnt$(i)=""thennt$(i)="[166]"
  155. 3150 ifnb$(i)=""thennb$(i)="[166]"
  156. 3160 ifne$(i)=""thenne$(i)="[166]"
  157. 3170 print#8,nm$(i)l$nt$(i)l$nb$(i)l$ne$(i)
  158. 3180 ifnm$(i)="[166]"thennm$(i)=""
  159. 3190 ifnt$(i)="[166]"thennt$(i)=""
  160. 3200 ifnb$(i)="[166]"thennb$(i)=""
  161. 3210 ifne$(i)="[166]"thenne$(i)=""
  162. 3220 nexti
  163. 3230 ifkl$=""thenkl$="[166]"
  164. 3240 ifhj$=""thenhj$="[166]"
  165. 3250 ifsj$=""thensj$="[166]"
  166. 3260 ifvn$=""thenvn$="[166]"
  167. 3270 ifnn$=""thennn$="[166]"
  168. 3280 print#8,kl$l$hj$l$sj$l$vn$l$nn$:close8
  169. 3290 ifkl$="[166]"thenkl$=""
  170. 3300 ifhj$="[166]"thenhj$=""
  171. 3310 ifsj$="[166]"thensj$=""
  172. 3320 ifvn$="[166]"thenvn$=""
  173. 3330 ifnn$="[166]"thennn$=""
  174. 3340 input#15,a$,b$,c$,d$:close15:ifval(a$)=0then500
  175. 3350 sys50622:goto500
  176. 3500 print"[147]diskettenverwaltung:":print:print
  177. 3510 print" 1[154] > stundenplan laden":print
  178. 3520 print" 2[154] > stundenplan speichern":print
  179. 3530 print" 3[154] > stundenplaene auflisten":print
  180. 3540 print" 4[154] > directory auflisten":print
  181. 3550 print" 5[154] > stundenplaene loeschen":print
  182. 3560 print" 6[154] > programme loeschen":print
  183. 3570 print" 7[154] > zurueck ins hauptmenue":print:print
  184. 3580 printtab(10);"ihre wahl (1-7) ? ";
  185. 3590 sysgt,7,a$
  186. 3600 print"[147]":ifa$="1"thenprint"stundenplan laden:[154]"
  187. 3610 i=1:ifa$="1"thenpoke2,3:sys49152:input"[144]";a$:ifa$<>"abbruch"then1000
  188. 3620 ifa$="2"then3000
  189. 3630 ifa$="3"thenpoke2,1:goto3900
  190. 3640 ifa$="4"theni=0:poke2,0:goto3900
  191. 3650 ifa$="5"thenpoke2,3:print"stundenplaene loeschen:[154]":sys49152:goto3690
  192. 3660 ifa$="6"theni=0:print"programme loeschen:[154]":poke2,2:sys49152:goto3690
  193. 3670 ifa$="7"then500
  194. 3680 ifa$="abbruch"then3500
  195. 3690 input"[144]";a$:ifa$="abbruch"then3500
  196. 3800 print"[147]loeschen von ";:ifi=0thenprint"programmen:[154]"
  197. 3810 ifi=1thenprint"stundenplaenen:[154]":a$=a$+".st"
  198. 3820 print:print"";a$;"[154] wird geloescht"
  199. 3830 close15:open15,8,15:print#15,"s:";a$:print:input#15,a$,b$,c$,c$
  200. 3840 close15:ifrn=-1thenreturn
  201. 3850 ifval(a$)=1thenprint"datei geloescht":print:gosub900:goto500
  202. 3860 ifval(a$)<20then500
  203. 3870 sys50622:goto500
  204. 3900 ifi=1thena$="stundenplaene auf diskette:[154]"
  205. 3910 ifi=0thena$="directory :[154]"
  206. 3920 printa$:print
  207. 3930 print" (feuer/space = pause"
  208. 3940 print" joystick oben-unten/ taste= halt)":print:gosub900
  209. 3950 sys49152
  210. 3960 poke211,11:poke214,24:sys58732:print"_[146] oder joystick links[146]";
  211. 3970 geta$:ifa$="_"then3500
  212. 3980 ifpeek(56320)=123then3500
  213. 3990 goto3970
  214. 4000 print"[147]ausdrucken:[154]":print:print"sind sie sicher (j/n) ? ";
  215. 4010 geta$:ifa$=""then4010
  216. 4020 if(a$<>"j")and(a$<>"[202]")then500
  217. 4030 printa$:print:print"o.k.,ihr stundenplan wird ausgedruckt":ifst%=0then500
  218. 4040 poke211,2:poke214,8:sys58732:print"[154]space = pause"
  219. 4050 a$="":close4:open4,4
  220. 4060 a$="[176][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192]"
  221. 4070 a$=a$+"[192][192][192][192][192][192][192][192][192][192][174]":gosub50:ona%goto500,4040
  222. 4080 a$="[221]"+vn$+" "+nn$:
  223. 4090 fori=1to(77-len(nn$)-len(vn$)-1):a$=a$+" ":nexti:a$=a$+"[221]":gosub50
  224. 4100 ona%goto500,4040:l$="[221]                                       "
  225. 4110 l$=l$+"                                      [221]":a$=l$:gosub50
  226. 4120 ona%goto500,4040:a$="[221]                         ":print#4,chr$(15);a$;
  227. 4130 a$="stundenplan":print#4,chr$(14);a$;chr$(15);
  228. 4140 a$="                              [221]":gosub50:ona%goto500,4040
  229. 4150 a$=l$:gosub50:ona%goto500,4040
  230. 4160 a$="[221]klasse: "+kl$+"     "+hj$+". halbjahr":j=len(a$)
  231. 4170 fori=jto(66-len(sj$)):a$=a$+" ":nexti:a$=a$+"schuljahr: "+sj$+"[221]":gosub50
  232. 4180 ona%goto500,4040
  233. 4190 a$="[171][192][192][192][192][192][192][192][192][192][192][192][178][192][192][192][192][192][192][192][192][192][192][178][192][192][192][192][192][192][192][192][192][192][178][192][192][192][192][192][192][192][192][192][192][178][192][192][192][192][192][192][192][192][192][192][178][192]"
  234. 4200 a$=a$+"[192][192][192][192][192][192][192][192][192][178][192][192][192][192][192][192][192][192][192][192][179]":gosub50:ona%goto500,4040
  235. 4210 a$="[221]           [221]  montag  [221] dienstag [221] mittwoch [221]donnerstag[221]  freitag [221]"
  236. 4220 a$=a$+"  samstag [221]":gosub50:ona%goto500,4040
  237. 4230 ll$="[171][192][192][192][192][192][192][192][192][192][192][192][219][192][192][192][192][192][192][192][192][192][192][219][192][192][192][192][192][192][192][192][192][192][219][192][192][192][192][192][192][192][192][192][192][219][192][192][192][192][192][192][192][192][192][192][219][192]"
  238. 4240 ll$=ll$+"[192][192][192][192][192][192][192][192][192][219][192][192][192][192][192][192][192][192][192][192][179]":a$=ll$:gosub50:ona%goto500,4040
  239. 4250 fori=1tost%:a$="[221]"+str$(i)+". stunde [221]":forj=1to6
  240. 4260 ii=len(f$(j,i)):ifii=0thena$=a$+"          ":goto4290
  241. 4270 ifii<10thenforjj=1toint((10-ii)/2+.99):a$=a$+" ":nextjj
  242. 4280 a$=a$+f$(j,i):ifii<9thenfori1=(jj+ii)to10:a$=a$+" ":nexti1
  243. 4290 a$=a$+"[221]":nextj:gosub50:ifa%<>0then4320
  244. 4300 a$="[221]           [221]          [221]          [221]          [221]          [221] "
  245. 4310 a$=a$+"         [221]          [221]":gosub50:ifa%=0then4330
  246. 4320 i=99:next:ona%goto500,4040
  247. 4330 i1=len(zb$(i)):i2=len(ze$(i)):a$="[221]"
  248. 4340 ifi1<5thenforii=1to(5-i1):a$=a$+" ":nextii
  249. 4350 a$=a$+zb$(i)+"-"
  250. 4360 ifi2<5thenforii=1to(5-i1):a$=a$+" ":nextii
  251. 4370 a$=a$+ze$(i)+"[221]"
  252. 4380 forj=1to6
  253. 4390 ii=len(r$(j,i)):ifii=0thena$=a$+"          ":goto4420
  254. 4400 ifii<10thenforjj=1to(int((10-ii)/2+.99)):a$=a$+" ":nextjj
  255. 4410 a$=a$+r$(j,i):ifii<9thenfori1=(jj+ii)to10:a$=a$+" ":nexti1
  256. 4420 a$=a$+"[221]":nextj:gosub50:ifa%<>0goto4440
  257. 4430 ifi<>st%thena$=ll$:gosub50:ifa%=0thennext:goto4450
  258. 4440 i=99:next:ona%goto500,4040
  259. 4450 a$="[171]":ifno%=0thena$="[173]"
  260. 4460 a$=a$+"[192][192][192][192][192][192][192][192][192][192][192][177][192][192][192][192][192][192][192][192][192][192][177][192][192][192][192][192][192][192][192][192][192][177][192][192][192][192][192][192][192][192][192][192][177][192][192][192][192][192][192][192][192][192][192][177][192]"
  261. 4470 a$=a$+"[192][192][192][192][192][192][192][192][192][177][192][192][192][192][192][192][192][192][192][192]":ll$="[179]":ifno%=0thenll$="[189]"
  262. 4480 a$=a$+ll$:gosub50:ona%goto500,4040:ifno%=0thengoto4570
  263. 4490 a$="[221]nachmittagsunterricht:                                            "
  264. 4500 a$=a$+"           [221]":gosub50:ona%goto500,4040:a$=l$:gosub50:ona%goto500,4040
  265. 4510 fori=1tono%:a$="[221] "+nt$(i)+"s: "+nm$(i)+" ("+nb$(i)+" uhr-"+ne$(i)+" uhr)"
  266. 4520 j=len(a$):forii=jto77:a$=a$+" ":nextii:a$=a$+"[221]":gosub50:ifa%<>0then4540
  267. 4530 a$=l$:gosub50ifa%=0thennext
  268. 4540 i=99:next:ona%goto500,4040
  269. 4550 a$="[173][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192]"
  270. 4560 a$=a$+"[192][192][192][192][192][192][192][192][192][189]":gosub50:ona%goto500,4040
  271. 4570 a$="                                                       "
  272. 4580 a$=a$+"(c) 1989 by ralf nikolai":gosub50:goto500
  273. 5000 print"[147]kuerzel:[154]":print:print
  274. 5010 print"anstatt der vollstaendigen faecherbe-":print
  275. 5020 print"zeichnungen koennen auch kuerzel einge-":print
  276. 5030 print"geben werden, die der computer auto-":print
  277. 5040 print"matisch durch die ausfuehrlichen be-":print
  278. 5050 print"zeichnungen ersetzt (ein-/ausschaltbar)":print:print
  279. 5060 print" 1 [154]> kuerzel ansehen":print
  280. 5070 print" 2 [154]> kuerzel aendern":print
  281. 5080 print" 3 [154]> kuerzel speichern":print
  282. 5090 print" 4 [154]> zurueck ins hauptmenue":print
  283. 5100 print:printtab(10);"ihre wahl (1-4) ? ";
  284. 5110 sysgt,4,a$:print"[154]":onval(a$)goto5200,5300,5600,500
  285. 5200 print"[147]kuerzel ";:ifks%=0thenprint" ausgeschaltet:[154]":goto5220
  286. 5210 print" eingeschaltet:[154]"
  287. 5220 ifk%=0then5000
  288. 5230 print:fori=1tok%:print" kuerzel: ";kk$(i);tab(17);"fach: ";kl$(i):nexti
  289. 5240 gosub900:goto5000
  290. 5300 print"[147]kuerzel aendern:[154]"
  291. 5310 poke211,0:poke214,3:sys58732:print"kuerzelkennung ";
  292. 5320 ifks%=0thenprint"aus[154]"
  293. 5330 ifks%=1thenprint"ein[154]"
  294. 5340 geta$:ifa$=""then5340
  295. 5350 ifasc(a$)=13then5380
  296. 5360 ifks%=1thenks%=0:goto5310
  297. 5370 ks%=1:goto5310
  298. 5380 ifks%=0then5000
  299. 5390 print:print"weiter ? ";
  300. 5400 geta$:ifa$=""then5400
  301. 5410 if(a$="j")or(a$="[202]")or(asc(a$)=13)thenprint"j":print:goto5430
  302. 5420 goto5000
  303. 5430 a$=str$(k%):rn=26:gosub800
  304. 5440 a$="":print"wie viele kuerzel (1-20) ";:sysip,2:inputa$
  305. 5450 k%=val(a$):if(k%<1)or(k%>20)thenk%=20:print"[145]";:goto5440
  306. 5460 print:fori=1tok%
  307. 5470 iflen(kk$(i))=0then5490
  308. 5480 a$=kk$(i):rn=11:gosub800
  309. 5490 kk$(i)="":print" kuerzel [154]";:sysip,2:inputkk$(i):ifi=1then5530
  310. 5500 ii=0:forrn=1to(i-1):ifkk$(i)=kk$(rn)thenii=1:rn=i-1
  311. 5510 nextrn:ifii=0then5530
  312. 5520 print"schon belegt![145]":goto5550
  313. 5530 iflen(kk$(i))>0then5560
  314. 5540 print"zu kurz![145]"
  315. 5550 kk$(i)=left$(kk$(i),2):print"[145]";:goto5470
  316. 5560 a$=kl$(i):rn=14:gosub800:kl$(i)="":print"       fach [154]";:sysip,10:inputkl$(i)
  317. 5570 iflen(kl$(i))>0then5590
  318. 5580 kl$(i)=left$(kl$(i),10):print"zu kurz![145]":print"[145]";:goto5560
  319. 5590 nexti:goto5000
  320. 5600 print"[147]kuerzel abspeichern:[154]":print
  321. 5610 print"sind sie sicher (j/n) ? ";
  322. 5620 geta$:ifa$=""then5620
  323. 5630 if(a$<>"j")and(a$<>"[202]")and(asc(a$)<>13)then5000
  324. 5640 print"j":print:print"diskette mit komplan einlegen":print
  325. 5650 gosub900:rn=-1:a$="komplan.kuerzel":gosub3830
  326. 5660 close15:close8:open15,8,15:open8,8,8,"0:komplan.kuerzel,p,w"
  327. 5670 print#8,k%:fori=1tok%:print#8,kk$(i):print#8,kl$(i):nexti:close8
  328. 5680 input#15,a$,b$,c$,c$:close15:ifval(a$)=0then5000
  329. 5690 print:sys50622:goto5000
  330. 6000 close15:close8:open15,8,15:open8,8,8,"komplan.kuerzel,p,r"
  331. 6010 j=0:input#8,k%:ifk%<1thenj=1:close8:goto6100
  332. 6020 fori=1tok%:input#8,kk$(i):input#8,kl$(i):nexti:close8
  333. 6100 open8,8,8,"0:komplan.zeiten,p,r":input#8,st%
  334. 6110 fori=1tost%:input#8,zb$(i):input#8,ze$(i):ifzb$(i)="[166]"thenzb$(i)=""
  335. 6120 ifze$(i)="[166]"thenze$(i)=""
  336. 6130 nexti:close8:input#15,i,b$,c$,c$:close15:i=i+j:if(i=0)and(k%>0)thenreturn
  337. 6140 print"[147]complan diskette einlegen[154]"
  338. 6150 print:printtab(10);"taste[146]":print:print"falls fehler unbehebbar q[154]"
  339. 6160 geta$:ifa$=""then6160
  340. 6170 ifa$<>"q"then6000
  341. 6180 ifk%<1thenk%=1:kk$(1)="rn":kl$(1)="r.nikolai"
  342. 6190 return
  343. 6200 print:print"komplan diskette einlegen[154]":gosub900:rn=-1:a$="komplan.zeiten":gosub3830
  344. 6210 close15:close8:open15,8,15:open8,8,8,"0:komplan.zeiten,p,w":print#8,st%
  345. 6220 fori=1tost%:print#8,zb$(i):ifzb$(i)=""thenprint#8,"[166]"
  346. 6230 print#8,ze$(i):ifze$(i)=""thenprint#8,"[166]"
  347. 6240 nexti:close8:input#15,a$,b$,c$,c$:ifval(a$)=0then500
  348. 6250 print:sys50622:goto500
  349. 7000 if(ks%=0)or(k%=0)thenreturn
  350. 7010 forrn=1tok%:if(f$(i,j))<>(kk$(rn))then7040
  351. 7020 f$(i,j)=kl$(rn):poke211,17+len(zb$(j))+len(ze$(j)):poke214,peek(214)-1
  352. 7030 sys58732:printf$(i,j):rn=k%
  353. 7040 nextrn:return
  354. 7100 if((i=1)and(j=1))or(ks%=0)thenreturn
  355. 7110 ifi=1then7170
  356. 7120 forrn=1toi-1:fornr=1tost%:iff$(i,j)<>f$(rn,nr)then7160
  357. 7130 yy=peek(214):xx=peek(211):poke211,xx+11:poke214,yy:sys58732
  358. 7140 printr$(rn,nr):poke211,xx:poke214,yy:sys58732:rn=i:nr=st%
  359. 7150 nextnr,rn:return
  360. 7160 nextnr,rn
  361. 7170 fornr=1tost%:iff$(i,j)<>f$(i,nr)then7200
  362. 7180 yy=peek(214):xx=peek(211):poke211,xx+11:poke214,yy:sys58732
  363. 7190 printr$(i,nr):poke211,xx:poke214,yy:sys58732:nr=st%
  364. 7200 nextnr:return
  365. 10000 datamontag,dienstag,mittwoch,donnerstag,freitag,samstag
  366.